Voilà un jeu bien intéressant qui voulait reprendre (un peu) le principe du jeu SIMON.

Je l'ai programmé à la fin des années 90 sur mon HP-41C. Ici, il n'est ni question de couleurs,
ni question de rapidité. Il suffit d'avoir suffisamment d'oreille pour pouvoir associer une lettre à un son.

Il existe deux modes d'utilisation : Jeu et Test. Pour cela, il suffit d'appuyer sur la touche H qui fera
apparaître ou disparaître l'indicateur binaire 0 (0 = mode Test).

En lançant le jeu en mode test, vous pouvez jouer avec les touches de A à E (du grave
au plus aiguë), la lettre appuyée s'affichera alors à l'écran cumulant les autres essais mais il n'y aura pas
de "* RESULTAT *"...

Avant de lancer le jeu, vérifiez que vous n'êtes pas en mode test (il suffit alors d'appuyer sur H pour en sortir).

Jouons donc en appuyant sur F.

ECOUTEZ... 4 sons sont émis.
A VOUS : Il faut saisir la bonne suite avec les touches A à E. Les indicateurs binaires 1234 vont s'afficher.
* RESULTAT * À la quatrième frappe, le résultat tombe :) Deux possibilités donc :
PAS GLOP... suivi de la solution lettrée et pour chacune d'elle la tonalité correspondante.
... BRAVO Vous avez tout bon... et droit à une jolie mélodie.

Afin de me faciliter la saisie du listing ci-dessous, je crée ces trois raccourcis :

ASN "BST" TAN       touche J
ASN "x≠y?" CHS      touche O
ASN "TONE" EEX      touche P

Le guillemet précise le mode ALPHA et s'il est suivi d'un crochet, un APPEND. Le caractère _ indique un espace.




01 LBL"RNDM
02 RCL 00
03 9821
04 *
05 .211327
06 +
07 FRC
08 STO 00
09 5
10 *
11 INT
12 5
13 +
14 STO 01
15 RTN
16 LBL 05
17"[A
18 RTN
19 LBL 06
20"[B
21 RTN
22 LBL 07
23"[C
24 RTN
25 LBL 08
26"[D
27 RTN
28 LBL 09
29"[E
30 RTN
31 LBL"JT
32 FC?C 00
33 SF 00
34 CLA
35 RTN
36 LBL"SIMON
37 STO 13
38"__ECOUTEZ...
39 AVIEW


40 3.00601
41 STO 02
42 LBL"BOUCLE
43 XEQ"RNDM
44 RCL 01
45 STO IND 02
46 ISG 02
47 GTO"BOUCLE
48 CLA
49 TONE IND 03
50 TONE IND 04
51 TONE IND 05
52 TONE IND 06
53 8
54 STO 07
55 XEQ"INIT
56"[A_VOUS_:_
57 AVIEW
58 RTN
59 LBL"INIT
60 CF 01
61 CF 02
62 CF 03
63 CF 04
64 RTN
65 LBL"TA
66 5
67 GTO 01
68 LBL"TB
69 6
70 GTO 01
71 LBL"TC
72 7
73 GTO 01
74 LBL"TD
75 8
76 GTO 01
77 LBL"TE
78 9


79 LBL 01
80 STO 08
81 TONE IND 08
82 XEQ IND 08
83 AVIEW
84 FS? 00
85 RTN
86 FS? 04
87 RTN
88 1
89 ST+ 07
90 RCL 08
91 STO IND 07
92 RCL 07
93 8
94 -
95 SF IND X
96 FC? 04
97 RTN
98"*_RESULTAT_*
99 AVIEW
100 BEEP
101 RCL 03
102 RCL 09
103 X≠Y?
104 GTO 02
105 RCL 04
106 RCL 10
107 X≠Y?
108 GTO 02
109 RCL 05
110 RCL 11
111 X≠Y?
112 GTO 02
113 RCL 06
114 RCL 12
115 X≠Y?
116 GTO 02
117"[...BRAVO


118 AVIEW
119 BEEP
120 TONE 7
121 TONE 6
122 GTO 03
123 LBL 02
124"[PAS_GLOP...
125 AVIEW
126 TONE 2
127 TONE 3
128 TONE 1
129 TONE 2
130 CLA
131 XEQ IND 03
132 TONE IND 03
133"[
134 AVIEW
135 PSE
136 XEQ IND 04
137 TONE IND 04
138"[
139 AVIEW
140 PSE
141 XEQ IND 05
142 TONE IND 05
143"[
144 AVIEW
145 PSE
146 XEQ IND 06
147 TONE IND 06
148"[
149 AVIEW
150 LBL 03
151 PSE
152 XEQ"INIT
153 VIEW 13
154 END

De plus, il est nécessaire d'assigner certaines étiquettes aux touches A, B, C, D, E, F et H.

ASN "TA" ∑+         touche A
ASN "TB" 1/x        touche B
ASN "TC" √x         touche C
ASN "TD" LOG        touche D
ASN "TE" LN         touche E
ASN "SIMON" x↔y     touche F
ASN "JT" SIN        touche H

Titi